Modified Perfect Balance System

[rjeaton1]

Modified Perfect Balance System



nolinks://vlsroulette.com/index.php?action=downloads;sa=view;id=352

[RXGuru]

Hello

This new system posted here requires an enchancement for Roulette Xtreme.  So you must download the newest version 2.3.4.3 nolinks://nolinks.uxsoftware.com/pages/download.html for this system to run correctly.

What's new with RX

1. New action command:  Round  - will round to the nearest whole number.  (i.e. 1.789 becomes 2)
2. New action command: Truncate - will remove anything after the decimal and leave the integer.  (i.e. 1.789 becomes 1)

Syntax:  Round Record "number" Data  (if record "number" data had a value of 1.45, then Round will round to 1 because 1.45 is less than 1.5).  If it was 1.56, then Round would round to 2 because it is above 1.5

Syntax: Truncate Record "number" Data (if record "number" data had 1.78, then Truncate would remove .78 and leave the number 1). 

These new commands as well as others will be documented in our help files when our new release is ready.  But I needed to let you all know so you can test this system correctly.

Many regards

RXGuru

[coetser]

Hi RJ

Can this modified system be used on a no zero table and if so can you tell me the changes i need to make in the codes for this.

Thanks
Coetser

[RXGuru]

Hello

The code changes are here for non-zero tables.

RX Gurue

Code Select Expand

System "Non-Zero Perfect Balance System"
{
  ********************************
  *                                                      *
  * RX Scripting by UXSoftware                *
  *                                                      *
  *   May 2009 - changed June 4, 2009      *
  *                                                      *
  ********************************
}
Method "main"
Begin
    While Starting a New Session
    Begin
        Call "Initialize"
        Call "Input"
    End

    While on Each Spin
    Begin
        Add 1 to record "spin counter" data
        Track Last Number for 37 times to record "tracked numbers" layout
       
        if record "spin counter" data < 10
        begin
            //Count the number of repeats
            Call "Count numbers that appeared"

            //This section looks for a Completed Street
            Call "Check if a street completes"

            //Fin a number that has appeared more than 3 times
            //** NOTE: If you only want 3 instead of >=3 then change
            //the >=3 to just 3
            Call "Find numbers that appeared three times"
           
            if Flag "reset" is true
            begin
                Call "Reset"
            end
           
            Set Flag "street check" to False
            Exit
        end
       
        Call "Check for win"

        //Count the number of repeats
        Call "Count numbers that appeared"

        //Find numbers that qualify (repeated twice)
        Call "Find numbers that appeared twice"

        //Find numbers that qualify by last 1 in a street
        Call "Find last number in streets"

        Call "Calc progression"

        //if the bet is over 100 units, QUIT and start over
        If record "progression" data > 100
        Begin
            Call "Reset"
           
            Exit
        end

        //Place bets
        Put 100% of record "progression" data to record "numbers" layout list
    End
End

Method "Calc progression"
Begin
    //make sure all numbers have current progression bets
    Call "Set progression bets on numbers"
   
    //Math calculations
    //1st - do (Current Bankroll - Current bet layout totals)
    Put 100% of Bankroll to record "tmp amount" data
    Subtract 100% of record "bet totals" data from record "tmp amount" data

    //2nd - Bankroll at start of session - (results from 1st calc)
    Put 100% of record "start bankroll" data to record "amount" data
    Subtract 100% of record "tmp amount" data from record "amount" data

    //3rd - divide results by 30
    Divide 100% of record "aggressive level" data to record "amount" data

    //4th - add .5 to force Round UP to nearest whole number
    Add .5 to record "amount" data

    //5th - Round function - new Action command for RX Scripting
    Round record "amount" data

    //6th - if we are less than 0, then set to 1
    if record "amount" data <= 0 begin Put 1 on record "amount" data end
   
    Put 100% of record "amount" data to record "progression" data

    //set new calculated progression bets on all numbers
    Call "Set progression bets on numbers"
end

Method "Set progression bets on numbers"
Begin
    Put 0 on record "bet totals" data
    Put 1 on record "numbers" layout index
    Put 1 on record "numbers" data index

    Loop until record "numbers" layout index > record "numbers" layout count
    begin
        Put 100% of record "progression" data to record "numbers" data
        Add 100% of record "numbers" data to record "bet totals" data

        Add 1 to record "numbers" layout index
        Add 1 to record "numbers" data index
    end
end

Method "Count numbers that appeared"
Begin
    Clear record "table" data
    Put 1 on record "tracked numbers" layout index

    Loop until record "tracked numbers" layout index > record "tracked numbers" layout count
    begin
        Put 1 on record "table" layout index

        Loop until record "table" layout index > record "table" layout count
        begin
            If record "tracked numbers" layout = record "table" layout
            begin
                Put 100% of record "table" layout index to record "table" data index
                Add 1 to record "table" data
                Set Max record "table" layout index
            end
           
            Add 1 to record "table" layout index
        end
       
        Add 1 to record "tracked numbers" layout index
    end
End

Method "Find numbers that appeared three times"
Begin
    Put 1 on record "table" data index

    Loop until record "table" data index > record "table" data count
    begin
        If  record "table" data >= 3
        begin
            Set Flag "reset" to True
            Return
        end

        Add 1 to record "table" data index
    end
End

Method "Find numbers that appeared twice"
Begin
    Put 1 on record "table" data index

    Loop until record "table" data index > record "table" data count
    begin
        If  record "table" data = 2
        begin
            Put 100% of record "table" data index to record "table" layout index

            If record "table" layout is not found in record "numbers" layout
            begin
                Set Max record "numbers" layout index
                Add 1 to record "numbers" layout index
                Copy record "table" layout to record "numbers" layout
            end
        end

        Add 1 to record "table" data index
    end
End

Method "Check if a street completes"
Begin
    Set Flag "street check" to True
    Set Flag "reset" to False

    //reuse the same routine for checking for complete streets
    Call "Find last number in streets"
End

method "Find last number in streets"
begin
    //street 1-3
    put 1 on record "start number" data
    put 3 on record "end number" data
    call "check street"
    //street 4-6
    put 4 on record "start number" data
    put 6 on record "end number" data
    call "check street"
    //street 7-9
    put 7 on record "start number" data
    put 9 on record "end number" data
    call "check street"
    //street 10-12
    put 10 on record "start number" data
    put 12 on record "end number" data
    call "check street"
    //street 13-15
    put 13 on record "start number" data
    put 15 on record "end number" data
    call "check street"
    //street 16-18
    put 16 on record "start number" data
    put 18 on record "end number" data
    call "check street"
    //street 19-21
    put 19 on record "start number" data
    put 21 on record "end number" data
    call "check street"
    //street 22-24
    put 22 on record "start number" data
    put 24 on record "end number" data
    call "check street"
    //street 25-27
    put 25 on record "start number" data
    put 27 on record "end number" data
    call "check street"
    //street 28-30
    put 28 on record "start number" data
    put 30 on record "end number" data
    call "check street"
    //street 31-33
    put 31 on record "start number" data
    put 33 on record "end number" data
    call "check street"
    //street 34-36
    put 34 on record "start number" data
    put 36 on record "end number" data
    call "check street"

end

method "check street"
begin
    If Flag "reset" is True begin Return end
   
    put 100% of record "start number" data to record "table" data index

    put 0 on record "count" data

    loop until record "table" data index > record "end number" data
    begin
        if record "table" data >0
        begin
            add 1 to record "count" data
        end

        add 1 to record "table" data index
    end

    If Flag "street check" is True
    begin
        if record "count" data = 3
        begin
            Set Flag "reset" to True
        end
       
        Return
    end
   
    If record "count" data not = to 2 begin Return end
   
    //We get here is there is 1 number left to complete a Street
    //So add to numbers list
    put 100% of record "start number" data to record "table" data index

    loop until record "table" data index > record "end number" data
    begin
        If  record "table" data = 0
        begin
            Put 100% of record "table" data index to record "table" layout index

            If record "table" layout is not found in record "numbers" layout
            begin
                Set Max record "numbers" layout index
                Add 1 to record "numbers" layout index
                Copy record "table" layout to record "numbers" layout
            end
        end

        Add 1 to record "table" data index
    end
end

//routine to deal with any wins
Method "Check for win"
Begin
    If Any Number Bet has won each time
    Begin
        Call "Reset"
        Exit
    end
End

//routine to initialize the system
Method "Initialize"
Begin
    Load No Zero Wheel
   
    Copy List [1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,
               20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36]
                    to record "table" layout

    Call "Reset"
   
    Copy Number 0 to record "number 0" layout
    Put 30 on record "aggressive level" data
End

Method "Reset"
Begin
    Clear record "numbers" layout
    Clear record "numbers" data
    Clear record "tracked numbers" layout
    Clear record "table" data
   
    Put 100% of Bankroll to record "start bankroll" data
    Put 1 unit on record "progression" data
    Put 0 on record "spin counter" data
    Set Flag "reset" to False
    Set Flag "street check" to False
End

//routine to ask for any data inputs
Method "Input"
Begin
    put 5000 to record "start bankroll" data
   
    Group
    begin
        Input Data "What is your starting bankroll?" to record "start bankroll" data

        Input Data "Enter your Aggressive Level." to record "aggressive level" data
    end

    put 100% of record "start bankroll" data to Bankroll
End



[RXGuru]

-