system "KREVS Non Repeaters v1"
{
*************************************
* System by KREV *
* on the VIP Lounge *
*************************************
Rx-ed by Sp1N-D1zZy
-------------------------------------
not 00-c0mpatible
-------------------------------------
Find 6 numbers that have only hit once and have a gap of 15 spins
between them, it can be more but no less,when the last number has
hit we play for a repeat for 15 spins until we have 6 numbers that
have only shown once, when we have are numbers we bet on them for
fifteen spins in hope of a repeat.heres the progression-
1, 1, 1, 1, 1, 2, 2, 3, 3, 4, 5, 6, 8, 10, 12 if no win,
we wait for 1 of the numbers to show again then carry on with the
second prog 15, 19, 23, 29, 36, 44, 55, 68, 85, 105, 131, 162, 201, 250, 310.
-------------------------------------
}
method "main"
begin
while starting new session
begin
call "Init"
exit
end
if flag"Bet" true
begin
call "Bet"
end else begin
call "Track"
end
end
method "Bet"
begin
if flag "Pro 1" true
begin
put 100% record"Progression 1"data record"Bet this"layout list
add 1 record"Progression 1"data index
if record"Progression 1"data index > record"Progression 1"data count
begin
set flag "Pro 1" false
end
end else begin
track last number for 1 spins record"Last Number"layout
if record"Last Number"layout found record"Bet this"layout
begin
set flag "Pro 2" true
end
end
if flag "Pro 2" true
begin
put 100% record"Progression 2"data record"Bet this"layout list
add 1 record"Progression 2"data index
if record"Progression 2"data index > record"Progression 2"data count
begin
call "Init"
exit
end
end
if net > 0
begin
call "Init"
exit
end
end
method "Track"
begin
add 1 record"Count"data
put 1 record"Single Wheel"layout index
loop until record"Single Wheel"layout index > record"Single Wheel"layout count
begin
if record"Single Wheel"layout found record"Current Block"layout
begin
add 1 record"Block"data
end
add 1 record"Single Wheel"layout index
end
if record"Block"data = 37
begin
call "Init"
exit
end else begin
put 0 record"Block"data
end
track last number for 1 spins record"Last Number"layout
copy record"Last Number"layout record"Current Block"layout
add 1 record"Current Block"layout index
clear record"Temp"layout
clear record"Singles"layout
if record"Count"data >= 1
begin
put 1 record"Single Wheel"layout index
clear record"Number Count"data
put 1 record"Number Count"data index
put 1 record"Current Block"layout index
loop until record"Current Block"layout index > record"Current Block"layout count
begin
loop until record"Single Wheel"layout index > record"Single Wheel"layout count
begin
if record"Current Block"layout = record"Single Wheel"layout
begin
add 1 record"Number Count"data
end
add 1 record"Number Count"data index
add 1 record"Single Wheel"layout index
end
put 1 record"Number Count"data index
put 1 record"Single Wheel"layout index
add 1 record"Current Block"layout index
end
put 1 record"Number Count"data index
put 1 record"Single Wheel"layout index
loop until record"Number Count"data index > record"Number Count"data count
begin
if record"Number Count"data = 1
begin
copy record"Single Wheel"layout record"Singles"layout
add 1 record"Singles"layout index
end
if record"Number Count"data = 0
begin
add 1 record"Not shown left"data
end
add 1 record"Single Wheel"layout index
add 1 record"Number Count"data index
end
add 100% record"Singles"layout index record"Not shown left"data
subtract 1 record"Not shown left"data
if record"Not shown left"data < 6
begin
call "Init"
exit
end
clear record"Not shown left"data
put 0 record"Current Block"layout index
loop until flag "Stop" true
begin
add 1 record"Current Block"layout index
if record"Current Block"layout found record"Singles"layout
or record"Current Block"layout index > record"Current Block"layout count
begin
set flag "Stop" true
end
end
set flag "Stop" false
clear record"Bet this"layout
copy record"Current Block"layout record"Bet this"layout
add 1 record"Bet this"layout index
loop until record"Current Block"layout index > record"Current Block"layout count
begin
add 12 record"Current Block"layout index
if record"Current Block"layout found record"Singles"layout
begin
copy record"Current Block"layout record"Bet this"layout
add 1 record"Bet this"layout index
end else begin
loop until flag "Stop" true
begin
add 1 record"Current Block"layout index
if record"Current Block"layout found record"Singles"layout
begin
copy record"Current Block"layout record"Bet this"layout
add 1 record"Bet this"layout index
set flag "Stop" true
end
if record"Current Block"layout index > record"Current Block"layout count
begin
set flag "Stop" true
end
end
set flag "Stop" false
end
end
set max record"Current Block"layout index
add 1 record"Current Block"layout index
if record"Bet this"layout count = 6
begin
set flag "Bet" true
call "Bet"
exit
end
end
end
method "Init"
begin
clear all records
load single wheel
copy list [0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,
27,28,29,30,31,32,33,34,35,36] record"Single Wheel"layout
set list [1,1,1,1,1,2,2,3,3,4,5,6,8,10,12] record"Progression 1"data
set list [15,19,23,29,36,44,55,68,85,105,131,162,201,250,310,310] record"Progression 2"data
set flag "Pro 1" true
set flag "Pro 2" false
set flag "Bet" false
put 0 all bets
put 0 record"Block"data
end
Happy Experimenting!
Dizzy. 8)