Line Bets -----RX coding needed Plz

[hideseek]

The system is simple:
Line1= 1-6
Line2= 7-12
Line 3 = 13-18
Line 4 = 19-24
Line 5 = 25-30
Line 6 = 31-36

If two lines hits 2 times in the past 6 spins play both lines for a maximum of 6 spins. Stop at win and retrack. Progression to use is 1,1,2,3,4,6.
Thanks for your attention and time
HS

[RXGuru]

Hello

Here is your requested system. 

RXGuru

Code Select Expand

system "line_bets"
{
********************
*  Coded by RXGuru *
*                  *
*  Aprin 19, 2009  *
********************

The system is simple:
Line1= 1-6
Line2= 7-12
Line 3 = 13-18
Line 4 = 19-24
Line 5 = 25-30
Line 6 = 31-36

If two lines hits 2 times in the past 6 spins play both lines for a maximum
of 6 spins. Stop at win and retrack. Progression to use is 1,1,2,3,4,6.

}
method "main"
begin
    while starting a new session
    begin
        //initialize here
        put 0 on record "spin count" data
        set list [1,1,2,3,4,6] to record "progression" data
        copy list [Line(1-6),Line(7-12),Line(13-18),Line(19-24),Line(25-30),Line(31-36)] to record "lines" layout
        clear record "tracked last 6 spins" layout
        set flag "ready to bet" to false
    end
   
    While on Each Spin
    begin
        //track last lines for past 6 spins
        track last Line for past 6 spins to record "tracked last 6 spins" layout
       
        if flag "ready to bet" is true
        begin
            if Any Line Bet has won each time
            begin
                set flag "ready to bet" to false
                clear record "tracked last 6 spins" layout  //clear to retrack
            end
            else
            begin
                add 1 to record "progression" data index
            end
        end

        if flag "ready to bet" is true
        begin
            add 1 to record "spin count" data

            if record "spin count" data > 6 then
            begin
                set flag "ready to bet" to false
                clear record "tracked last 6 spins" layout  //clear to retrack
            end
            else
            begin
                call "place bets"
            end
        end
       
        if flag "ready to bet" is false
        begin
            call "count hits"

            if record "line count" data = 2
            begin
                set flag "ready to bet" to true
                put 0 on record "spin count" data
                put 1 on record "progression" data index
                call "place bets"
            end
        end

    end
end

method "count hits"
begin
    clear record "lines" data //clear hit count

    put 1 on record "tracked last 6 spins" layout index

    //loop through past 6 spins to count lines
    loop until record "tracked last 6 spins" layout index > record "tracked last 6 spins" layout count
    begin
        //loop through all 6 lines and if one of them hits from past 6 spins
        //add to its record data section
        put 1 on record "lines" layout index

        loop until record "lines" layout index > record "lines" layout count
        begin
            if record "lines" layout = record "tracked last 6 spins" layout
            begin
                put 100% of record "lines" layout index to record "lines" data index
                add 1 to record "lines" data
                set max to record "lines" layout index
            end

            add 1 to record "lines" layout index
        end

        add 1 to record "tracked last 6 spins" layout index
    end

    //check if two lines has
    put 0 on record "line count" data

    //loop through all 6 lines data section and look for 2 hits
    //system will pick the first two that has hit twice in last 6 spins
    put 1 on record "lines" data index

    loop until record "lines" data index > record "lines" data count
    begin
        if record "lines" data = 2
        begin
            add 1 to record "line count" data
        end

        add 1 to record "lines" data index
    end
end

method "place bets"
begin
    put 1 on record "lines" data index

    loop until record "lines" data index > record "lines" data count
    begin
        if record "lines" data = 2
        begin
            put 100% of record "lines" data index to record "lines" layout index
            put 100% of record "progression" data to record "lines" layout
        end

        add 1 to record "lines" data index
    end
end

[RXGuru]

-